// Connexion à Google
Cnx est une gglConnexion
...

// Récupération du tableau des agendas disponibles
tabAgendas est un tableau de gglAgenda
tabAgendas = GglListeAgenda(Cnx)

// Parcours 
tabAgendasParcoursEvénement est un gglAgenda
UnAgenda est un gglAgenda
UnEvénement est un gglEvénement
UnLieu est un gglLieu

// Parcours de tous les agendas disponibles, on récupère les événements
POUR TOUT ÉLÉMENT UnAgenda DE tabAgendas
	Trace("Agenda " + UnAgenda.Titre + ...
		 " (mis à jour le " + DateVersChaîne(UnAgenda.DateMiseAJour[[À 8]]) + ...
		 " à " + HeureVersChaîne(UnAgenda.DateMiseAJour[[9 À]]) + ")") 
	tabAgendasParcoursEvénement = GglRécupèreAgenda(Cnx, UnAgenda.Identifiant)

	// Parcours de tous les événements de l'agenda en cours
	POUR TOUT UnEvénement DE tabAgendasParcoursEvénement
		Trace("------------------------------")
		Trace(UnEvénement.Titre)
		Trace("Du " + DateVersChaîne(UnEvénement.DateDébut[[À 8]]) + ...
			  " à " + HeureVersChaîne(UnEvénement.DateDébut[[9 À]]) + ")" + ...
			  " au " + DateVersChaîne(UnEvénement.DateFin[[À 8]]) + " à " + ...
			  HeureVersChaîne(UnEvénement.DateFin[[9 À]]) + ")")  

		// Parcours des lieux de l'événement
		POUR TOUT ÉLÉMENT UnLieu DE UnEvénement.Lieu
			Trace("Lieu de l'événement : " + UnLieu.Valeur + "//" + UnLieu.Libellé)
		FIN
	FIN
FIN

MaConnexion est une gglConnexion
MonAgenda est un gglAgenda
MonEvénement est un gglEvénement
tabMesAgendas est un tableau de gglAgenda
i est un entier

...

// Récupération de l'agenda
tabMesAgendas = GglListeAgenda(MaConnexion)
i = TableauCherche(tabMesAgendas, tcLinéaire, "Titre", "Test")
SI i = -1 ALORS
	MonAgenda.Titre = "Test"
SINON
	MonAgenda = GglRécupèreAgenda(MaConnexion, "Test")
FIN

// Création de l'événement
MonEvénement.Contenu = "STG"
MonEvénement.DateDébut = "20160906000000"
MonEvénement.DateFin = "20160907000000"
MonEvénement.JournéeEntière = Vrai
MonEvénement.Titre = "STG"


// Ajout de l'événement dans l'agenda et écriture de celui-ci
Ajoute(MonAgenda.Evénement, MonEvénement)
SI PAS GglEcrit(MaConnexion, MonAgenda) ALORS
	Erreur(ErreurInfo())
FIN

MaConnexion est une gglConnexion
MonAgenda est un gglAgenda
MonEvénement est un gglEvénement
tabMesAgendas est un tableau de gglAgenda
i est un entier
sMonEvénement est une chaîne

...

// Récupération de l'Agenda
tabMesAgendas = GglListeAgenda(MaConnexion)
i = TableauCherche(tabMesAgendas, tcLinéaire, "Titre", "STG")
SI i = -1 ALORS
	MonAgenda.Titre = "Test"
SINON
	// Récupération de l'événement
	MonAgenda = GglRécupèreAgenda(MaConnexion, "STG")
	MonEvénement = MonAgenda.Evénement[1]
FIN

sMonEvénement += [RC] + "Contenu : " + MonEvénement.Contenu
sMonEvénement += [RC] + "DateDébut : " + MonEvénement.DateDébut
sMonEvénement += [RC] + "DateFin : " + MonEvénement.DateFin
sMonEvénement += [RC] + "JournéeEntière : " + MonEvénement.JournéeEntière
sMonEvénement += [RC] + "Titre : " + MonEvénement.Titre

Info(sMonEvénement)