// Chargement du pdf
Mon_pdf est un pdfDocument = chemin_pdf

// Vérification de la signature
// Lance la procédure uniquement si une signature invalide est détectée
PDFVérifieSignatures(Mon_pdf, Proc_vérification)

PROCÉDURE Proc_vérification(Doc_pdf, Indice_Signature, Code_Erreur)
// Traitement du code d'erreur
texte_erreur est une chaîne
SELON Code_Erreur
	CAS pdfSignatureInvalide : texte_erreur = ChaîneConstruit("Signature %1 non valide", Indice_Signature)
	CAS pdfCertificatExpiré : texte_erreur = ChaîneConstruit("Le certificat de la signature %1 est expiré", Indice_Signature)
	CAS pdfModifiéAprèsSignature : texte_erreur = "Le PDF a été modifié après signature"
FIN
// Identification de la signature posant problème 
SI Indice_Signature > 0 ALORS
	texte_erreur += RC + RC
	// Informations sur la signature
	soit buf_signature = PDFRécupèreSignature(Doc_pdf, Indice_Signature)
	certif est un Certificat = CertificatExtrait(buf_signature)
	texte_erreur += ChaîneConstruit([
		Signature numéro %1
		Émetteur : %2
		Nom : %3
		Date de début de validité : %4
		Date de Fin de validité : %5
		Date de la signature : %6
	],
	Indice_Signature,
	certif.Emetteur,
	certif.Nom,
	DateVersChaîne(certif.DateValiditéDébut),
	DateVersChaîne(certif.DateValiditéFin),
	DateVersChaîne(PDFRécupèreDateSignature(Doc_pdf, Indice_Signature)))
FIN
// Si 
SI ErreurDétectée ALORS
	texte_erreur += RC + RC+ ErreurInfo(errRésumé)
	// Affiche l'erreur
	Info(texte_erreur)
	// On ne continue pas le parcours des signatures
	RENVOYER Faux
SINON
	// On continue le parcours des signatures
	// Si une signature fausse est trouvée, la procédure est relancée. 
	RENVOYER Vrai
FIN