DOCUMENTATION EN LIGNE
DE WINDEVWEBDEV ET WINDEV MOBILE

Aide / WLangage / Gestion des bases de données / HFSQL / Fonctions HFSQL
  • Borne minimale et borne maximale sur une rubrique clé de type texte ou clé composée
  • Filtre et parcours filtré
  • Condition de sélection
  • Activation/Désactivation d'un filtre
  • Filtre sur une clé composée
  • Fichiers de données non HFSQL
WINDEV
WindowsLinuxUniversal Windows 10 AppJavaEtats et RequêtesCode Utilisateur (MCU)
WEBDEV
WindowsLinuxPHPWEBDEV - Code Navigateur
WINDEV Mobile
AndroidWidget AndroidiPhone/iPadWidget IOSApple WatchMac CatalystUniversal Windows 10 App
Autres
Procédures stockées
Définit et active un filtre sur un fichier de données, une vue ou une requête.
Après son exécution, les cas suivants sont les plus fréquents :
  • le filtre ne peut pas être créé : la fonction <Source>.Filtre renvoie une chaîne vide. La fonction HErreur permet de récupérer l'identifiant de l'erreur.
  • le filtre est créé : la fonction <Source>.Filtre renvoie la clé de parcours optimale à utiliser pour réaliser le parcours du fichier de données, de la vue ou de la requête.
Exemple
// Filtre simple avec une condition :
// Rechercher les clients d'une ville
 
CléParcours est une chaîne
maville est une chaîne
 
maville = "MONTPELLIER"
CléParcours = Client.Filtre("VILLE='" + maville + "'")
Client.LitPremier(CléParcours)
TANTQUE Client.EnDehors() = Faux
// Traitement de l'enregistrement
...
Client.LitSuivant(CléParcours)
FIN
// Annule le filtre
Client.DésactiveFiltre()
// Filtre réalisé avec une clé de parcours bornée et une condition :
// la clé de parcours est fixée
 
CléParcours est une chaîne
// Filtre les factures comprises entre le 1/1/2005 et le
// 31/12/2005 dont le total est supérieur à 1500 Euros TTC
// avec une remise dont le type est passé en paramètres (rubrique texte)
CléParcours = Facture.Filtre(DateFacture, "20050101", "20051231", ...
ChaîneConstruit("TotalTTC>1500 ET TypeRemise = '%1'" + , ...
Remplace(sTypeRemise, "'", "\'")))
// La fonction Remplace permet de préfixer les apostrophes
// que peut contenir sTypeRemise d'un antislash
SI CléParcours <> "" ALORS
Facture.LitPremier(CléParcours)
TANTQUE Facture.EnDehors() = Faux
// Traitement de l'enregistrement : envoi d'une lettre de remerciement
Envoi_Lettre()
Facture.LitSuivant(CléParcours)
FIN
FIN
...
// Annule le filtre
Facture.DésactiveFiltre()
Syntaxe

Filtre construit avec une clé de parcours bornée et une condition Masquer les détails

<Résultat> = <Source>.Filtre(<Clé de parcours> , <Borne minimale> [, <Borne maximale> [, <Condition de sélection>]])
<Résultat> : Chaîne de caractères
Rubrique de parcours. Correspond :
  • soit à la clé de parcours du fichier de données si le filtre est activé.
  • soit à une chaîne vide ("") si le filtre ne peut pas être mis en place.
<Source> : Type correspondant à la source spécifiée
Nom du fichier de données, de la vue HFSQL ou de la requête manipulé.
<Clé de parcours> : Chaîne de caractères
Nom de la rubrique clé utilisée pour parcourir le fichier de données, la vue ou la requête. Cette rubrique doit être une clé de parcours du fichier de données, de la vue ou de la requête. C'est sur cette rubrique que s'appliquent les bornes minimales et maximales.
<Borne minimale> : Type de la rubrique de parcours
Valeur minimale incluse de la rubrique de parcours (si la clé de parcours est définie avec un sens de parcours ascendant dans l'analyse). Les enregistrements correspondant à cette valeur minimale seront inclus dans le filtre. Dans le cas d'un parcours descendant (c'est-à-dire si la clé de parcours est définie avec un sens de parcours descendant dans l'analyse), c'est la valeur maximale de la rubrique de parcours.
Le type de ce paramètre doit correspondre au type de la rubrique de parcours. Par exemple, si la rubrique de parcours est une chaîne, la borne minimale doit être une chaîne.
<Borne maximale> : Type de la rubrique de parcours, paramètre optionnel
Valeur maximale incluse de la rubrique de parcours (cas d'un parcours ascendant). Les enregistrements correspondant à cette valeur maximale seront inclus dans le filtre. Le type de ce paramètre doit correspondre au type de la rubrique de parcours. Par exemple, si la rubrique de parcours est une chaîne, la borne maximale doit être une chaîne.
Dans le cas d'un parcours descendant, c'est la valeur minimale de la rubrique de parcours.
Si ce paramètre n'est pas précisé, la borne maximale du filtre correspond à la valeur du paramètre <Borne minimale>.
<Condition de sélection> : Chaîne de caractères optionnelle
Condition de sélection pour créer le filtre (voir Notes). Cette condition de sélection peut être une chaîne de caractères au format Ansi ou Unicode.

Filtre construit avec une condition Masquer les détails

<Résultat> = <Source>.Filtre(<Condition de sélection>)
<Résultat> : Chaîne de caractères
Rubrique de parcours. Correspond :
  • soit à la clé de parcours du fichier de données si le filtre est activé
  • soit à une chaîne vide si le filtre ne peut pas être mis en place
<Source> : Type correspondant à la source spécifiée
Nom du fichier de données, de la vue HFSQL ou de la requête manipulé.
<Condition de sélection> : Chaîne de caractères
Condition de sélection pour créer le filtre (voir NOTES). Cette condition de sélection peut être une chaîne de caractères au format Ansi ou Unicode.
Remarques

Borne minimale et borne maximale sur une rubrique clé de type texte ou clé composée

Si la borne minimale et la borne maximale sont identiques :
  • pour réaliser un filtre à l'identique sur une valeur, il suffit de préciser cette valeur dans le paramètre "Borne min".
    Par exemple, pour sélectionner les clients dont le nom correspond à "Dupon" :
    Client.Filtre(Nom, "Dupon")

    Le client "Dupontel" ne sera pas sélectionné.
  • pour réaliser un filtre générique sur une valeur, il suffit de :
    • compléter la borne minimale avec la constante hValMin pour lui donner la valeur minimale.
    • compléter la borne maximale avec la constante hValMax pour lui donner la valeur maximale.
    Par exemple, pour sélectionner les clients dont le nom commence par "Dupon" :
    Client.Filtre(Nom, "Dupon" + hValMin, "Dupon" + hValMax)

    Les clients "Dupon" et "Dupontel" seront sélectionnés.
Remarques :
  • La constante hValMin est équivalente à Caract(0).
  • La constante hValMax est équivalente à Caract(255).

Filtre et parcours filtré

Après l'exécution de la fonction <Source>.Filtre, le parcours du fichier de données doit obligatoirement être effectué sur la rubrique renvoyée par la fonction <Source>.Filtre. Si une autre rubrique est utilisée pour le parcours du fichier de données, le filtre ne sera pas pris en compte.
Lorsqu'un filtre est défini et activé sur un fichier de données (une vue ou une requête), tout enregistrement lu correspond au filtre. Si il n'y a plus d'enregistrement correspondant au filtre lors du parcours :
  • la fonction <Source>.EnDehors renvoie Vrai.
  • l'enregistrement en cours correspond au dernier enregistrement lu avec le filtre.
Par exemple :
Sur un fichier de données filtré, après la fonction :l'enregistrement en cours est :
HLitPremierle premier enregistrement du fichier de données correspondant au filtre
HLitDernierle dernier enregistrement du fichier de données correspondant au filtre
HLitSuivant (ou HAvance)l'enregistrement suivant (ou le nième suivant) correspondant au filtre
HLitPrécédent (ou HRecule)l'enregistrement précédent (ou le nième précédent) correspondant au filtre

Condition de sélection

La syntaxe générale d'une condition a la forme suivante :
"NomCli>'Dupont' et (CodePos=34 ou CodePos=32)"
Les opérateurs acceptés sont variables en fonction du type des rubriques utilisées dans la condition :
>Plus grandValable pour tous les types
>=Plus grand ou égalValable pour tous les types
<Plus petitValable pour tous les types
<>DifférentValable pour tous les types
<=Plus petit ou égalValable pour tous les types
 =Strictement égalValable pour tous les types
]Contient : prend en compte la casse des caractèresValable pour les types chaîne uniquement
]=Commence par : prend en compte la casse des caractèresValable pour les types chaîne uniquement
~]Contient : ne prend pas en compte la casse des caractèresValable pour les types chaîne uniquement
~~Égalité très souple : ne différencie pas les caractères majuscules des caractères minuscules, ne tient pas compte des espaces situés avant et après la chaîne à tester, ne tient pas compte des caractères accentués minuscules, ne tient pas compte des espaces et des ponctuations à l'intérieur des chaînes.Valable pour les types chaîne uniquement
~=Environ égal : ne tient pas compte des espaces à droite, ni des accents, ni de la casse des caractèresValable pour les types chaîne uniquement
Java Les opérateurs ~~ et ~= ne doivent pas être utilisés. Ces opérateurs sont interdits.
Remarques sur la condition de sélection :
  • Les chaînes constantes doivent être encadrées de simples quotes.
  • Si le nom de la rubrique contient des simples quotes, elles doivent être doublées.
    Par exemple : ‘Rubrique‘‘avec‘‘quotes‘
  • Les comparaisons entre chaînes se font en fonction des paramètres spécifiés pour les index.
  • Les mémos binaires et les clés composées ne peuvent pas faire partie d'une condition de sélection.
    Pour les clés composées, il est conseillé d'utiliser la première syntaxe. Il n'est pas possible d'utiliser la syntaxe suivante :
    NomFichier.Filtre("CLECOMP~]'AAA' ET CLECOMP]='" + ...
    NomFichier.ConstruitValClé(CLECOMP, 0) + "'")
  • Si une chaîne de caractères (constante ou variable) contient une simple quote, il faut faire précéder cette simple quote par un anti-slash ( \ ).
  • Pour optimiser le parcours du filtre, utilisez la fonction <Source>.StatCalcule sur le fichier de données avant de créer le filtre. En effet, le moteur HFSQL analyse la condition de sélection et s'appuie ensuite sur ces statistiques pour déterminer les rubriques les plus discriminantes qui permettront d'optimiser le parcours du fichier de données.
  • Cette condition de sélection peut être une chaîne de caractères au format Ansi ou Unicode.

Activation/Désactivation d'un filtre

La fonction <Source>.DésactiveFiltre permet de désactiver un filtre.
La fonction <Source>.ActiveFiltre permet de ré-activer un filtre.
Lorsque le fichier de données (la requête ou la vue) est fermé (fonction <Source>.Ferme par exemple), le filtre est supprimé.
A un même instant, il ne peut exister qu'un seul filtre sur un fichier de données (une requête ou une vue). Si la fonction <Source>.Filtre est utilisée plusieurs fois, seul le dernier filtre sera pris en compte : le(s) filtre(s) précédent(s) seront supprimés.
WINDEVUniversal Windows 10 AppJavaCode Utilisateur (MCU)HFSQL ClassicHFSQL Client/ServeurProcédures stockées

Filtre sur une clé composée

Pour construire un filtre sur une clé composée, plusieurs méthodes sont disponibles :
  • Méthode 1 : Utilisation d'une liste de valeurs dans la fonction <Source>.Filtre.
  • Méthode 2 : Utilisation de l'instruction POUR TOUT.
  • Méthode 3 : Utilisation de la fonction <Source>.ConstruitValClé.
Pour plus de détails sur l'utilisation des clés composées dans les filtres, consultez Clés composées et Filtres.
Exemple d'utilisation de la méthode 1 : Utilisation d'une liste de valeurs
La valeur de la clé composée sur laquelle le filtre doit être effectué peut être directement construite dans la fonction <Source>.Filtre grâce à la syntaxe suivante :
HFiltre(<Nom du fichier>, <Nom de la clé composée>,
[<Liste des valeurs pour la borne minimale de la clé composée>],
[<Liste des valeurs pour la borne maximale de la clé composée>])
Exemple : Recherche de tous les enregistrements du fichier CLIENT dont le nom et le prénom sont compris entre "AA","Barnabé" et "Philomène" et "Tartuffe".
Client.Filtre(NomPrenom, ["AA","Philomène"], ["Barnabé","Tartuffe"])
Dans cet exemple, "AA","Zorro" est renvoyé par le filtre alors que "Philomène","Zorro" n'est pas renvoyé.
Exemple : Recherche de tous les enregistrements du fichier Taches dont les tâches sont comprises entre le 15/03/2021 00h00 et le 25/03/2021 00h00.
Taches.Filtre(DateDébutTacheHeureDébutTache, [20210315,0000], [20210325,0000])
WINDEVJavaCode Utilisateur (MCU)Procédures stockéesOLE DBConnecteurs Natifs (Accès Natifs)

Fichiers de données non HFSQL

Composante : wd290hf.dll
Version minimum requise
  • Version 25
Documentation également disponible pour…
Commentaires
Cliquez sur [Ajouter] pour publier un commentaire

Dernière modification : 20/06/2023

Signaler une erreur ou faire une suggestion | Aide en ligne locale